home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 023 - Big U Macroworks.dsk / STARTUP.bas < prev    next >
BASIC Source File  |  2019-02-16  |  3KB  |  41 lines
  1. 10 V$ = "01-APR-86"
  2. 20  PRINT  CHR$(21): HOME : NORMAL :D$ =  CHR$(4):KP =  -16384:KR =  -16368:CS =  -958:BP$ =  CHR$(7): PRINT D$"PREFIX/"
  3. 30 MACHID =  PEEK(49048):IIEIIC = 1:BO$ = "________________": IF MA <128  THEN BO$ = "              ":IIEIIC = 0
  4. 40  FOR I = 0 TO 9: READ A: POKE I,A: NEXT 
  5. 50  DATA  169,0,106,106,144,2,230,9,96,0
  6. 60  POKE 1,MACHID: CALL 0:SCRN80 =  PEEK(9)
  7. 70  IF   NOT IIEIIC  THEN 180
  8. 80  PRINT D$"-BIG.U": REM  80-COLUMN SCREEN
  9. 90  FOR I = 0 TO 2000: NEXT 
  10. 100  VTAB 23: PRINT 
  11. 110  FOR I = 1 TO 28:X =  PEEK(KP): ON X = 155 GOTO 170: POKE 1403,I -1: PRINT " ";: POKE 1403,I
  12. 120  PRINT "- p e s   r s   e u n - ";
  13. 130  POKE 1403,53 -I:C =  PEEK(49200)
  14. 140  PRINT "   l a e p e s r t r    ";: NEXT 
  15. 150  POKE 1403,28: PRINT "- please press return -";
  16. 160  WAIT KP,128:X =  PEEK(KP): IF X < >141  AND X < >155  THEN 160
  17. 170  POKE KR,0
  18. 180  HOME : PRINT  CHR$(21): PRINT D$"PREFIX/"
  19. 190  SPEED= 255: POKE 49166,0: ONERR  GOTO 350
  20. 200  VTAB 1: HTAB 2: PRINT  LEFT$(BO$,13): HTAB 2: INVERSE : PRINT "  THE BIG U  ": HTAB 3: NORMAL : PRINT : HTAB 3: PRINT "COPYRIGHT (C) 1985": HTAB 3: PRINT "BY RANDY BRANDT": HTAB 3: PRINT "BEAGLE BROS, INC."
  21. 210  PRINT : VTAB 2: HTAB 39 - LEN(V$): PRINT " "V$: VTAB 7: HTAB 2: PRINT BO$
  22. 220  HTAB 2: INVERSE : PRINT " RUN A PROGRAM: ": NORMAL : PRINT : PRINT "  <F> FILE.MOVER": PRINT : PRINT "  <C> CRT.WRITER": PRINT : PRINT "  <K> KEYCAT.80": PRINT : PRINT "  <S> SEE CATALOG"
  23. 230  PRINT : PRINT "  <N> NOTES (MANUAL UPDATE)": PRINT : PRINT "  <Q> QUIT"
  24. 240  VTAB 21: HTAB 2: PRINT BO$;BO$
  25. 250  HTAB 2: INVERSE : PRINT " PLEASE SELECT ONE OF THE ABOVE ";: NORMAL : CALL CS: VTAB 22
  26. 260  GOSUB 370: ON A$ = "Q" GOTO 320: ON A$ = "S" GOTO 330
  27. 270  ON A$ = "F" GOTO 280: ON A$ = "C" GOTO 290: ON A$ = "N" GOTO 310: ON A$ = "K" GOTO 300: PRINT  CHR$(7);: GOTO 260
  28. 280  PRINT : ON IIEIIC = 0 GOTO 400: PRINT D$"-FILE.MOVER"
  29. 290  PRINT : ON IIEIIC = 0 GOTO 400: PRINT D$"-CRT.WRITER"
  30. 300  PRINT : ON SCRN80 = 0 GOTO 390: PRINT : PRINT D$"-KEYCAT.80": END 
  31. 310  PRINT : PRINT D$"-NOTES"
  32. 320  VTAB 20: PRINT : CALL  -958: PRINT : END 
  33. 330  HOME : PRINT D$"CAT"
  34. 340  PRINT : PRINT "PRESS <RETURN> TO CONTINUE: ";: GET X$: GOTO 180
  35. 350  IF  PEEK(222) = 6  THEN  VTAB 21: PRINT : CALL CS: PRINT BP$: PRINT "  CAN'T FIND IT; PRESS A KEY ";: GET X$: GOTO 240
  36. 360  POKE 216,0: RESUME 
  37. 370  WAIT KP,128:A =  PEEK(KP): POKE KR,0:A = A -128: IF A >95  THEN A = A -32
  38. 380 A$ =  CHR$(A): RETURN 
  39. 390  VTAB 21: PRINT : CALL CS: PRINT BP$: PRINT "  80-COLUMNS REQUIRED; PRESS A KEY ";: GET X$: GOTO 240
  40. 400  VTAB 21: PRINT : CALL CS: PRINT BP$: PRINT "  IIE OR IIC REQUIRED; PRESS A KEY ";: GET X$: GOTO 240
  41. 410  VTAB 22: PRINT : CALL  -958: END