home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Wonky Flux Batch 2019 02
/
Wonky_Flux_Batch_2019-02.zip
/
Wonky Flux Batch 2019-02
/
023 - Big U Macroworks.dsk
/
STARTUP.bas
< prev
next >
Wrap
BASIC Source File
|
2019-02-16
|
3KB
|
41 lines
10 V$ = "01-APR-86"
20 PRINT CHR$(21): HOME : NORMAL :D$ = CHR$(4):KP = -16384:KR = -16368:CS = -958:BP$ = CHR$(7): PRINT D$"PREFIX/"
30 MACHID = PEEK(49048):IIEIIC = 1:BO$ = "________________": IF MA <128 THEN BO$ = " ":IIEIIC = 0
40 FOR I = 0 TO 9: READ A: POKE I,A: NEXT
50 DATA 169,0,106,106,144,2,230,9,96,0
60 POKE 1,MACHID: CALL 0:SCRN80 = PEEK(9)
70 IF NOT IIEIIC THEN 180
80 PRINT D$"-BIG.U": REM 80-COLUMN SCREEN
90 FOR I = 0 TO 2000: NEXT
100 VTAB 23: PRINT
110 FOR I = 1 TO 28:X = PEEK(KP): ON X = 155 GOTO 170: POKE 1403,I -1: PRINT " ";: POKE 1403,I
120 PRINT "- p e s r s e u n - ";
130 POKE 1403,53 -I:C = PEEK(49200)
140 PRINT " l a e p e s r t r ";: NEXT
150 POKE 1403,28: PRINT "- please press return -";
160 WAIT KP,128:X = PEEK(KP): IF X < >141 AND X < >155 THEN 160
170 POKE KR,0
180 HOME : PRINT CHR$(21): PRINT D$"PREFIX/"
190 SPEED= 255: POKE 49166,0: ONERR GOTO 350
200 VTAB 1: HTAB 2: PRINT LEFT$(BO$,13): HTAB 2: INVERSE : PRINT " THE BIG U ": HTAB 3: NORMAL : PRINT : HTAB 3: PRINT "COPYRIGHT (C) 1985": HTAB 3: PRINT "BY RANDY BRANDT": HTAB 3: PRINT "BEAGLE BROS, INC."
210 PRINT : VTAB 2: HTAB 39 - LEN(V$): PRINT " "V$: VTAB 7: HTAB 2: PRINT BO$
220 HTAB 2: INVERSE : PRINT " RUN A PROGRAM: ": NORMAL : PRINT : PRINT " <F> FILE.MOVER": PRINT : PRINT " <C> CRT.WRITER": PRINT : PRINT " <K> KEYCAT.80": PRINT : PRINT " <S> SEE CATALOG"
230 PRINT : PRINT " <N> NOTES (MANUAL UPDATE)": PRINT : PRINT " <Q> QUIT"
240 VTAB 21: HTAB 2: PRINT BO$;BO$
250 HTAB 2: INVERSE : PRINT " PLEASE SELECT ONE OF THE ABOVE ";: NORMAL : CALL CS: VTAB 22
260 GOSUB 370: ON A$ = "Q" GOTO 320: ON A$ = "S" GOTO 330
270 ON A$ = "F" GOTO 280: ON A$ = "C" GOTO 290: ON A$ = "N" GOTO 310: ON A$ = "K" GOTO 300: PRINT CHR$(7);: GOTO 260
280 PRINT : ON IIEIIC = 0 GOTO 400: PRINT D$"-FILE.MOVER"
290 PRINT : ON IIEIIC = 0 GOTO 400: PRINT D$"-CRT.WRITER"
300 PRINT : ON SCRN80 = 0 GOTO 390: PRINT : PRINT D$"-KEYCAT.80": END
310 PRINT : PRINT D$"-NOTES"
320 VTAB 20: PRINT : CALL -958: PRINT : END
330 HOME : PRINT D$"CAT"
340 PRINT : PRINT "PRESS <RETURN> TO CONTINUE: ";: GET X$: GOTO 180
350 IF PEEK(222) = 6 THEN VTAB 21: PRINT : CALL CS: PRINT BP$: PRINT " CAN'T FIND IT; PRESS A KEY ";: GET X$: GOTO 240
360 POKE 216,0: RESUME
370 WAIT KP,128:A = PEEK(KP): POKE KR,0:A = A -128: IF A >95 THEN A = A -32
380 A$ = CHR$(A): RETURN
390 VTAB 21: PRINT : CALL CS: PRINT BP$: PRINT " 80-COLUMNS REQUIRED; PRESS A KEY ";: GET X$: GOTO 240
400 VTAB 21: PRINT : CALL CS: PRINT BP$: PRINT " IIE OR IIC REQUIRED; PRESS A KEY ";: GET X$: GOTO 240
410 VTAB 22: PRINT : CALL -958: END